ROS2-BDI

PDDL domain example

The pddl file below is supposed to be a simple domain definition for a ROS2-BDI agent which acts as a cleaner.

  ;; domain file: cleaner-domain.pddl

  (define (domain cleaner-domain)

      (:requirements 
        :strips :typing 
        :fluents :durative-actions
      )

      ;; Types ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
      (:types
          waypoint
          robot
      );; end Types ;;;;;;;;;;;;;;;;;;;;;;;;;

      (:predicates
          (in ?r - robot ?wp - waypoint)
          (workfree ?r - robot)
          (recharging_station ?wp - waypoint)
          (cleaned ?wp - waypoint)
      )

      (:functions
          (battery_charge ?r - robot)
      )

      (:durative-action movetoward
          :parameters (?r - robot ?wp_from ?wp_to - waypoint)
          :duration (= ?duration 4)
          :condition (and
              (at start (in ?r ?wp_from))
              (at start (workfree ?r))
              (at start (> (battery_charge ?r) 20))
              (over all (> (battery_charge ?r) 10))
          )
          :effect (and
              (at start (not(workfree ?r)))
              (at start (not(in ?r ?wp_from)))
              (at end (in ?r ?wp_to))
              (at end (workfree ?r))
              (at end (decrease (battery_charge ?r) 10))
          )
      )

      (:durative-action doclean
          :parameters (?r - robot ?wp - waypoint)
          :duration (= ?duration 4)
          :condition (and
              (at start (workfree ?r))
              (at start (> (battery_charge ?r) 30))
              (over all (> (battery_charge ?r) 10))
              (over all (in ?r ?wp))
          )
          :effect (and
              (at start (not(workfree ?r)))
              (at end (workfree ?r))
              (at end (cleaned ?wp))
              (at end (decrease (battery_charge ?r) 20))
          )
      )

      (:durative-action recharge
          :parameters (?r - robot ?wp - waypoint)
          :duration (= ?duration 4)
          :condition (and
              (at start (workfree ?r))
              (over all (in ?r ?wp))
              (over all (recharging_station ?wp))
          )
          :effect (and
              (at start (not(workfree ?r)))
              (at end (workfree ?r))
              (at end (assign (battery_charge ?r) 100))
          )
      )

    )

Instances of interest might be robotic agent (itself or others) and points of interest in a map.
Predicates of interest are the following:

Actions essentially defines when, which and how properties are supposed to be and change before, after and/or during their executions. The cleaner agent we have envisioned can essentially move, clean and recharge. IT'S REALLY IMPORTANT THAT THE FIRST PARAMETER OF EVERY ROS2-BDI ACTION DEFINED IN ITS PDDL DOMAIN WITHOLDS THE REFERENCE TO ITS agent_id value . The user won't need to worry to put it there, if the provided python libraries are used to generate the launch description for the agent. The takeout information is that it's not possible to simply define a move, clean,... action, without leaving room in the first argument for a reference to the agent, so the proper action executor node (the one belonging to the agent) will be selected and triggered when the action needs to be run.
NOTE: This is not valid anymore if you break the default behaviour by setting agent_id_as_specialized_arg to false, go back here for further info.

Python bringup example

The following script can basically be copied and pasted in order to be tuned to comply with the user's needs. It allows to easily generate a launch description to boot up all the ROS2-BDI core and auxiliary nodes as well as an instance of PlanSys2 for the agent, while hiding all the complexity. User just needs to put the reference for the implemented Sensors and Actions. as below, specifying the required parameters and the needed tunable ones too.

                          
import sys
from ament_index_python.packages import get_package_share_directory

ros2_bdi_bringup_dir = get_package_share_directory('ros2_bdi_bringup')
sys.path.append(ros2_bdi_bringup_dir + '/launch/')
from bdi_agent import AgentLaunchDescription
from bdi_agent_skills import AgentAction
from bdi_agent_skills import AgentSensor

def generate_launch_description():
    AGENT_ID = 'cleaner'
    AGENT_GROUP_ID = 'cleaner'

    bdi_tests_share_dir = get_package_share_directory('ros2_bdi_tests')

    # perform moving toward
    action_movetoward = AgentAction(
        package='ros2_bdi_tests',
        executable='movetoward_bdi',
        name='movetoward'
    )

    # perform cleaning action
    action_doclean = AgentAction(
        package='ros2_bdi_tests',
        executable='doclean_bdi',
        name='doclean'
    )
    
    # recharging action
    action_recharge = AgentAction(
        package='ros2_bdi_tests',
        executable='recharge_bdi',
        name='recharge'
    )

    # waypoint sensor 
    wp_sensor = AgentSensor(
        package='ros2_bdi_tests',
        executable='wp_sensor',
        name='wp_sensor',
        specific_params=[
            {"init_sleep": 2}
        ])

    ld = AgentLaunchDescription(
        agent_id=AGENT_ID,
        agent_group=AGENT_GROUP_ID,
        init_params={
            'pddl_file': bdi_tests_share_dir + '/pddl/cleaner_simple/cleaner-domain.pddl',
            'init_bset': bdi_tests_share_dir + '/launch/init_cleaner_simple/init_bset.yaml',
            'init_dset': bdi_tests_share_dir + '/launch/init_cleaner_simple/init_dset.yaml',
            'autosub_prec': True,
            'autosub_cont': True,
            'reschedule_policy': 'NO_PREEMPT'
        },
        actions=[action_movetoward, action_doclean, action_recharge],
        sensors=[wp_sensor]
    ) 

    return ld
                          
                        

Launch Parameters